Crate Quest

Crate QuestBy jcGyo

For instructions, click:

You find yourself in a lush green field, grass stretches in all directions.
You see a stout wooden crate to the west.

Exits:

You can also see:

a glittering pendant

Save game as:

Really restart this game?

Display options

font:

font size:

Print room title in scroller:

Always

Landscape only

Never

List objects in scroller

Always

Landscape only

Never

This game was made with gruescript.

game Crate Quest # Game title
id SOKO 
author jcGyo
version 0.0.1
person 2
examine off 
wait off
#enable custom status for debugging
#status {$room}

thing crate1 a stout wooden crate
tags crate
loc x1y3

thing crate2 a sturdy wooden crate
tags crate
loc x3y4

thing pendant a glittering pendant
name the pendant
tags portable
loc x2y3
cverbs rub eat

verb take pendant
write pendant.display The pendant of Unduz
continue

verb rub pendant
say You rub the pendant of Unduz... the world shifts around you.
put crate1 $crate1oldloc
put crate2 $crate2oldloc
goto $playeroldloc

verb eat pendant
say You shove the pendant of Unduz into your mouth and swallow it in one gulp... the world disappears in a blur of colors.
put crate1 x1y3
put crate2 x3y4
goto x2y3

rule #tell the player if there is a crate in an adjacent room
all things
has $this crate
assign crateDesc $this.display
assign crateloc $this.loc
all dirs $room
eq $room.dir.$this $crateloc
say You see {$crateDesc} to the {$this}.

verb go
assign crate1oldloc crate1.loc
assign crate2oldloc crate2.loc
assign playeroldloc $room
select things
has $this crate
assign crateloc $this.loc
eq $room.dir.$direction $crateloc
!try pushcrate $this $direction: As you walk you push {$this.display} to the {$direction}.
say {$this.Display} blocks your path.

proc pushcrate crate direction
assign crateloc $crate.loc
assign newloc $crateloc.dir.$direction
isroom $newloc
!thingat crate1 $newloc
!thingat crate2 $newloc
put $crate $newloc

proc win
die You've pushed all of the crates onto the targets! You win! Thank you for playing!

rule
thingat crate1 x2y1
thingat crate2 x1y3
run win

rule
thingat crate2 x2y1
thingat crate1 x1y3
run win

rule
write x2y3.desc You find yourself in a lush green field, grass stretches in all directions.

# Rooms
room x1y1 You are in a green field.  Imposing brick walls stand to the North and the West.
east x2y1
south x1y2

room x2y1 You see an ominous rune etched into ground here.  Walls block your path to the North and the East.
west x1y1
south x2y2

room x1y2 You're in a grassy field.  A cheerful brick wall stands to the West.
north x1y1
east x2y2
south x1y3

room x2y2 You stand in the middle of a field.  A crumbling stone wall blocks your path to the East.
north x2y1
west x1y2
south x2y3

room x1y3 You see an ancient rune etched into the earth at your feet.  To your West another wall stares at you blankly.
north x1y2
east x2y3
south x1y4

room x2y3 You find yourself in a lush green field, grass stretches in all directions.<br>You see a stout wooden crate to the west.
north x2y2
west x1y3
east x3y3
south x2y4
tags start # the player starts here

room x3y3 Grass tickles your ankles as you stand in the field.  A stone wall silently crumbles to the North.
west x2y3
east x4y3
south x3y4

room x4y3 You find yourself in a corner of the field.  Magnificent walls tower to the North and East.
west x3y3
south x4y4

room x1y4 You stand in yet another part of the field.  A wall bullies you into not traveling West.
north x1y3
east x2y4
south x1y5

room x2y4 The lush green field gives way here to a rich emerald meadow.  You stand in the meadow.
west x1y4
north x2y3
east x3y4
south x2y5

room x3y4 You're not sure if this is a field or meadow, but it certainly is grassy.  A wall helpfully reminds you not to travel South from here.
west x2y4
north x3y3
east x4y4

room x4y4 You find yourself in a corner of a meadow.  You can't travel East or South because of the walls.
north x4y3
west x3y4

room x1y5 A shady spot in the field is provided by the walls to your West and South.
north x1y4
east x2y5

room x2y5 Looks like you're still in a field.  To the South and East you see, you guessed it, more walls.
north x2y4
west x1y5